Exceller

Calcul de la tranche d'imposition

Income Tax Bracket Calculation

Formule Excel : Calcul de la tranche d'impositionSommaire

Pour calculer l'impôt sur le revenu total sur la base de plusieurs tranches d'imposition, vous pouvez utiliser RECHERCHEV et une table de taux structurée comme indiqué dans l'exemple. La formule en G5 est :



 
= VLOOKUP (inc,rates,3,1)+(inc- VLOOKUP (inc,rates,1,1))* VLOOKUP (inc,rates,2,1)

où 'inc' (G4) et 'rates' (B5:D11) sont plages nommées , et la colonne D est un colonne d'aide qui calcule le total des impôts accumulés à chaque tranche.

Contexte et contexte

Le système fiscal américain est « progressif », ce qui signifie que les personnes ayant un revenu imposable plus élevé paient un taux d'imposition fédéral plus élevé. Les tarifs sont évalués entre parenthèses définies par un seuil supérieur et inférieur. Le montant du revenu qui tombe dans une tranche donnée est imposé au taux correspondant pour cette tranche. À mesure que le revenu imposable augmente, le revenu est imposé sur plus de tranches d'imposition. De nombreux contribuables paient donc plusieurs taux différents.





Dans l'exemple illustré, les tranches d'imposition et les taux s'appliquent aux déclarants uniques aux États-Unis pour l'année d'imposition 2019. Le tableau ci-dessous présente les calculs manuels pour un revenu imposable de 50 000 $ :

Support Calcul Impôt
dix% (9 700 $ - 0 $) x 10 % 970.00 $
12% (39 475 $ - 9 700 $) x 12% 3 573,00 $
22% (50 000 $ - 39 475 $) x 22 % 2 315,50 $
24% N / A 0,00 $
32% N / A 0,00 $
35% N / A 0,00 $
37% N / A 0,00 $

La taxe totale est donc de 6 858,50 $. (affiché comme 6 859 dans l'exemple illustré).



Remarques sur la configuration

1. Cette formule dépend de Fonction RECHERCHEV en « mode de correspondance approximative ». En mode de correspondance approximative, RECHERCHEV parcourra les valeurs de recherche dans un tableau (qui doit être trié par ordre croissant) jusqu'à ce qu'une valeur plus élevée soit trouvée. Ensuite, il 'reculera' et renverra une valeur de la ligne précédente. En cas de correspondance exacte, RECHERCHEV renverra les résultats de la ligne correspondante.

2. Pour que RECHERCHEV récupère les montants de taxe cumulés réels, ceux-ci ont été ajoutés au tableau en tant que colonne d'aide dans la colonne D. La formule dans D6, copiée vers le bas, est :

 
=((B6-B5)*C5)+D5

À chaque ligne, cette formule applique le taux de la ligne ci-dessus au revenu de cette tranche.

comment s'intégrer automatiquement dans Excel

3. Pour plus de lisibilité, ce qui suit plages nommées , sont définis : 'inc' (G4) et 'rates' (B5:D11).

Explication

Dans G5, la première RECHERCHEV est configurée pour récupérer la taxe cumulée au taux marginal avec ces entrées :

  • La valeur de recherche est 'inc' (G4)
  • La table de correspondance est « taux » (B5:D11)
  • Le numéro de colonne est 3, Taxe cumulative
  • Le type de correspondance est 1 = correspondance approximative
 
 VLOOKUP (inc,rates,3,1) // returns 4,543

Avec un revenu imposable de 50 000 $, RECHERCHEV, en mode de correspondance approximative, correspond à 39 475 et renvoie 4 543, la taxe totale pouvant atteindre 39 475 $.

Le deuxième RECHERCHEV calcule le revenu restant à imposer :

 
(inc- VLOOKUP (inc,rates,1,1)) // returns 10,525

calculé comme ceci :

(50 000-39 475) = 10 525

Enfin, le troisième RECHERCHEV obtient le taux d'imposition marginal (le plus élevé) :

 
 VLOOKUP (inc,rates,2,1) // returns 22%

Celui-ci est multiplié par le revenu calculé à l'étape précédente. La formule complète est résolue comme ceci :

 
= VLOOKUP (inc,rates,3,1)+(inc- VLOOKUP (inc,rates,1,1))* VLOOKUP (inc,rates,2,1) =4,543+(10525)*22% =6,859 

Taux marginaux et effectifs

La cellule G6 contient le taux marginal le plus élevé, calculé avec RECHERCHEV :

 
= VLOOKUP (inc,rates,2,1) // returns 22%

Le taux d'imposition effectif dans le G7 est l'impôt total divisé par le revenu imposable :

 
=G5/inc // returns 13.7%

Remarque : je suis tombé sur cette formule sur le blog de Jeff Lenning à l'Université Excel. C'est un excellent exemple de la façon dont RECHERCHEV peut être utilisé en mode de correspondance approximative, et aussi de la façon dont RECHERCHEV peut être utilisé plusieurs fois dans la même formule.

Auteur Dave Bruns


^